関数を用いたプログラム例3

プログラム例　9-3

#include <Arduino.h> // Arduino.h の読み込み

// ドットマトリクスLEDアノード側ピンの配列
int ledAnodePins[8] = {0, 2, 4, 5, 16, 17, 18, 19};
// ドットマトリクスLEDカソード側ピンの配列
int ledCathodePins[8] = {21, 22, 23, 25, 26, 27, 32, 33};
// 文字Aの点灯パターン
byte ledPatternA[8] = {
  0b00000000,
  0b00001000,
  0b00010100,
  0b00100010,
  0b00100010,
  0b00111110,
  0b00100010,
  0b00100010,
};
// ドットマトリクスLEDの点灯パターン（カソード側＝１行ずつ表示）
byte ledCathodePattern[8] = {
  0b00000001,
  0b00000010,
  0b00000100,
  0b00001000,
  0b00010000,
  0b00100000,
  0b01000000,
  0b10000000,
};

/*
 * ドットマトリクスLED初期設定関数
 */
void initLed() {

  // 各アノード・カソード端子の設定
  for(int i=0; i<8; i++) {

    // 入出力設定
    pinMode(ledAnodePins[i], OUTPUT);
    pinMode(ledCathodePins[i], OUTPUT);

    // 出力レベル設定（全消灯）
    digitalWrite(ledAnodePins[i], LOW);
    digitalWrite(ledCathodePins[i], HIGH);
  }
}

/*
 * ドットマトリクスLED点灯パターン設定関数
 * 引数: patternAnode 表示するパターン（ アノード側）
 *       patternCathode 表示するパターン（ カソード側）
 */
void setLed(byte patternAnode, byte patternCathode) {

  // カソード側のパターンを反転
  patternCathode = ~patternCathode;

  // 列および行の点灯設定
  for(int i=0; i<8; i++) {
    // i 列目に patternAnod の i ビット目の値を設定
    digitalWrite(ledAnodePins[i], bitRead(patternAnode, i));
    // i 行目に patternCathode の i ビット目の値を設定
    digitalWrite(ledCathodePins[i], bitRead(patternCathode, i));
  }
}

/*
 * setup 関数
 */
void setup() {
  /* ここにプログラムの最初に1回だけ実行したい処理を上から順に記述していきます */

  // シリアル通信を115200bpsで開始
  Serial.begin(115200);

  Serial.println("初期設定の開始");

  // ドットマトリクスLED初期設定
  initLed();

  Serial.println("初期設定の完了");
}

/*
 * loop 関数
 */
void loop() {
  /* ここにプログラム中で繰り返し実行したい処理を上から順に記述していきます */

  for(int i=0; i<8; i++) {
    // ドットマトリクスLEDのi行目を表示
    setLed(ledPatternA[i], ledCathodePattern[i]);
    // 時間待ち
    delay(1);
  }
}
Code language: Arduino (arduino)